Arduinoから MPU6050の値を取得してみる

　MPU6050（6軸センサー）をArduino経由で使ってみました。

　MPU6050の使い方を中心に、下の動画に使用したArduino側スケッチ（ソース）説明を備忘録として纏めておきます。

動作確認

　Processingを使用してリアルタイムで描画してます。なるべくシンプルで高速な処理をしたかったのでライブラリは使用しないでソース書いてます。（あまり変わらないかな？i2c通信はwire.hライブラリ仕様してます）今回はちゃんと3軸ベクトル計算したためyaw軸（z軸）回転もきちんと再現できてます。

MPU6050のセットアップ

void set_up_MPU6050() {
  Wire.beginTransmission(0x68);
  Wire.write(0x6B);
  Wire.write(0x00);
  Wire.endTransmission();

  //Gyro初期設定
  Wire.beginTransmission(0x68);
  Wire.write(0x1B);
  Wire.write(0x08);
  Wire.endTransmission();

  //加速度センサー初期設定
  Wire.beginTransmission(0x68);
  Wire.write(0x1C);
  Wire.write(0x10);
  Wire.endTransmission();

  //LPF設定
  Wire.beginTransmission(0x68);
  Wire.write(0x1A);
  Wire.write(0x03);
  Wire.endTransmission();
}

　▲セットアップ例です。

　最初に[0x68]よりデバイスを初期化というか起動します。

▼データシートより[0x6B]Register▼

　次にジャイロの初期設定。[0x1B]レジスタのbit4、bit3の2bitでジャイロのスケールレンジが設定できます。

▼レジスタ▼

▼またレンジによるLSB（スケールファクター）は▼

　角速度へ変換するときに必要な数値です。例ではレンジ：500deg/s、SF：65.5LSB/(deg/s)で設定してます。

　次に加速度センサーの初期設定。[0x1C]レジスタのbit4、bit3の2bitで加速度センサーのスケールレンジが設定できます。

▼レジスタ▼

▼LSB（スケールファクター）▼

　今回はレンジ：±8Ｇ、SF：4096LSB/Gで設定してます。

　最後にローパスフィルターの設定です。ローパスフィルターの設定もできるのですね。[0x1A]レジスタの下位3bitで設定できます。

▼レジスタ▼

　フィルター関係は難しくてよく理解できていないんですけどね・・。1次のローパスフィルターは大きくとると波形（値）が鈍って、遅れるという認識です。私の場合はセンサーに乗る高周波ノイズの除去にソフトで実装してたりします。今回は≒43Hzに設定してます。

　これで初期設定は完了。続いて値の読み出しです。

センサー値の読み出し

void readMPU6050() {
  Wire.beginTransmission(0x68);
  Wire.write(0x3B);
  Wire.endTransmission();
  Wire.requestFrom(0x68, 14);

  while (Wire.available() < 14);
  axRaw = Wire.read() << 8 | Wire.read();
  ayRaw = Wire.read() << 8 | Wire.read();
  azRaw = Wire.read() << 8 | Wire.read();
  temperatureRaw = Wire.read() << 8 | Wire.read();
  gxRaw = Wire.read() << 8 | Wire.read();
  gyRaw = Wire.read() << 8 | Wire.read();
  gzRaw = Wire.read() << 8 | Wire.read();
}

　加速度センサー（3軸）、デバイス温度、ジャイロ（3軸）の値を取り出します。検出値はそれぞれ16bit（2byte）の長さで、レジスタアドレス[0x3B]から順に14byteで格納されてます。

　ですので[0x3B]から14byte分のデータを要求。読みだした値を8bitずつ順に結合していけば生データの読み出し完了です。生データのままでは32767～-32768(2byte)のデータとなるためそれぞれ加速度、温度、角速度へ変換します。

　今回は割愛しますが、取得した値をキャリブレーションして、加速度、角速度へ変換、姿勢角計算して、ドリフト補正して、、、とすると記事冒頭のような3軸の傾きを表現できるようになります。ここら辺は要望があるようなら別途紹介したいと思います。

ソース全体

　
MPU6050から取得した生値をそのままシリアル出力しているスケッチです。

// 2017/10/14 imo lab.
// https://garchiving.com/

#include <Wire.h>

int16_t axRaw, ayRaw, azRaw, gxRaw, gyRaw, gzRaw, temperature;

void setup() {
  Serial.begin(9600);
  Wire.setClock(400000);
  Wire.begin();
  
  Wire.beginTransmission(0x68);
  Wire.write(0x6B);
  Wire.write(0x00);
  Wire.endTransmission();
  Wire.beginTransmission(0x68);
  Wire.write(0x1C);
  Wire.write(0x10);
  Wire.endTransmission();
  Wire.beginTransmission(0x68);
  Wire.write(0x1B);
  Wire.write(0x08);
  Wire.endTransmission();
  Wire.beginTransmission(0x68);
  Wire.write(0x1A);
  Wire.write(0x05);
  Wire.endTransmission();
}

void loop() {
  Wire.beginTransmission(0x68);
  Wire.write(0x3B);
  Wire.endTransmission();
  Wire.requestFrom(0x68, 14);
  while (Wire.available() < 14);
  axRaw = Wire.read() << 8 | Wire.read();
  ayRaw = Wire.read() << 8 | Wire.read();
  azRaw = Wire.read() << 8 | Wire.read();
  temperature = Wire.read() << 8 | Wire.read();
  gxRaw = Wire.read() << 8 | Wire.read();
  gyRaw = Wire.read() << 8 | Wire.read();
  gzRaw = Wire.read() << 8 | Wire.read();

  Serial.print(axRaw); Serial.print(",");
  Serial.print(ayRaw); Serial.print(",");
  Serial.print(azRaw); Serial.print(",");
  Serial.print(gxRaw); Serial.print(",");
  Serial.print(gyRaw); Serial.print(",");
  Serial.println(gzRaw);
}